source: OpenSC/configure.ac @ 07f7e93

Revision 07f7e93, 15.7 KB checked in by ludovic, 8 weeks ago (diff)

Remove libltdl: Detect libdl

Change-Id: I51e7de45c11823460e776492dcbd40e60583a7eb
  • Property mode set to 100644
Line 
1dnl -*- mode: m4; -*-
2
3AC_PREREQ(2.60)
4
5define([PACKAGE_VERSION_MAJOR], [0])
6define([PACKAGE_VERSION_MINOR], [12])
7define([PACKAGE_VERSION_FIX], [3])
8define([PACKAGE_SUFFIX], [-pre1])
9
10AC_INIT([opensc],[PACKAGE_VERSION_MAJOR.PACKAGE_VERSION_MINOR.PACKAGE_VERSION_FIX[]PACKAGE_SUFFIX])
11AC_CONFIG_AUX_DIR([.])
12AC_CONFIG_HEADERS([config.h])
13AC_CONFIG_MACRO_DIR([m4])
14AM_INIT_AUTOMAKE(foreign 1.10)
15
16OPENSC_VERSION_MAJOR="PACKAGE_VERSION_MAJOR"
17OPENSC_VERSION_MINOR="PACKAGE_VERSION_MINOR"
18OPENSC_VERSION_FIX="PACKAGE_VERSION_FIX"
19
20# LT Version numbers, remember to change them just *before* a release.
21#   (Code changed:                      REVISION++)
22#   (Oldest interface removed:          OLDEST++)
23#   (Interfaces added:                  CURRENT++, REVISION=0)
24OPENSC_LT_CURRENT="3"
25OPENSC_LT_OLDEST="3"
26OPENSC_LT_REVISION="0"
27OPENSC_LT_AGE="0"
28OPENSC_LT_AGE="$((${OPENSC_LT_CURRENT}-${OPENSC_LT_OLDEST}))"
29
30AC_CONFIG_SRCDIR([src/libopensc/sc.c])
31
32# silent build by default
33m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
34
35AC_CANONICAL_HOST
36AC_PROG_CC
37PKG_PROG_PKG_CONFIG
38AC_C_BIGENDIAN
39
40AC_ARG_WITH(
41        [cygwin-native],
42        [AS_HELP_STRING([--with-cygwin-native],[compile native win32])],
43        ,
44        [with_cygwin_native="no"]
45)
46
47dnl Check for some target-specific stuff
48test -z "${WIN32}" && WIN32="no"
49test -z "${CYGWIN}" && CYGWIN="no"
50case "${host}" in
51        *-*-solaris*)
52                CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
53                LDFLAGS="${LDFLAGS} -L/usr/local/lib -R/usr/local/lib"
54        ;;
55        *-mingw*|*-winnt*)
56                WIN32="yes"
57                CPPFLAGS="${CPPFLAGS} -DWIN32_LEAN_AND_MEAN"
58                WIN_LIBPREFIX="lib"
59        ;;
60        *-cygwin*)
61                AC_MSG_CHECKING([cygwin mode to use])
62                CYGWIN="yes"
63                if test "${with_cygwin_native}" = "yes"; then
64                        AC_MSG_RESULT([Using native win32])
65                        CPPFLAGS="${CPPFLAGS} -DWIN32_LEAN_AND_MEAN"
66                        CFLAGS="${CFLAGS} -mno-cygwin"
67                        WIN32="yes"
68                else
69                        AC_MSG_RESULT([Using cygwin])
70                        CPPFLAGS="${CPPFLAGS} -DCRYPTOKI_FORCE_WIN32"
71                        WIN_LIBPREFIX="cyg"
72                        AC_DEFINE([USE_CYGWIN], [1], [Define if you are on Cygwin])
73                fi
74        ;;
75esac
76
77AC_ARG_ENABLE(
78        [strict],
79        [AS_HELP_STRING([--enable-strict],[enable strict compile mode @<:@disabled@:>@])],
80        ,
81        [enable_strict="no"]
82)
83
84AC_ARG_ENABLE(
85        [pedantic],
86        [AS_HELP_STRING([--enable-pedantic],[enable pedantic compile mode @<:@disabled@:>@])],
87        ,
88        [enable_pedantic="no"]
89)
90
91AC_ARG_ENABLE(
92        [zlib],
93        [AS_HELP_STRING([--enable-zlib],[enable zlib linkage @<:@detect@:>@])],
94        ,
95        [enable_zlib="detect"]
96)
97
98AC_ARG_ENABLE(
99        [readline],
100        [AS_HELP_STRING([--enable-readline],[enable readline linkage @<:@detect@:>@])],
101        ,
102        [enable_readline="detect"]
103)
104
105AC_ARG_ENABLE(
106        [openssl],
107        [AS_HELP_STRING([--enable-openssl],[enable openssl linkage @<:@detect@:>@])],
108        ,
109        [enable_openssl="detect"]
110)
111
112AC_ARG_ENABLE(
113        [openct],
114        [AS_HELP_STRING([--enable-openct],[enable openct linkage @<:@disabled@:>@])],
115        ,
116        [enable_openct="no"]
117)
118
119AC_ARG_ENABLE(
120        [pcsc],
121        [AS_HELP_STRING([--disable-pcsc],[disable pcsc support @<:@enabled@:>@])],
122        ,
123        [enable_pcsc="yes"]
124)
125
126AC_ARG_ENABLE(
127        [ctapi],
128        [AS_HELP_STRING([--enable-ctapi],[enable CT-API support @<:@disabled@:>@])],
129        ,
130        [enable_ctapi="no"]
131)
132
133AC_ARG_ENABLE(
134        [minidriver],
135        [AS_HELP_STRING([--enable-minidriver],[enable minidriver on Windows @<:@disabled@:>@])],
136        ,
137        [enable_minidriver="no"]
138)
139
140AC_ARG_ENABLE(
141        [man],
142        [AS_HELP_STRING([--disable-man],[disable installation of manuals @<:@enabled for none Windows@:>@])],
143        ,
144        [enable_man="detect"]
145)
146
147AC_ARG_ENABLE(
148        [doc],
149        [AS_HELP_STRING([--enable-doc],[enable installation of documents @<:@disabled@:>@])],
150        ,
151        [enable_doc="no"]
152)
153
154AC_ARG_WITH(
155        [xsl-stylesheetsdir],
156        [AS_HELP_STRING([--with-xsl-stylesheetsdir=PATH],[docbook xsl-stylesheets for svn build @<:@detect@:>@])],
157        [xslstylesheetsdir="${withval}"],
158        [xslstylesheetsdir="detect"]
159)
160
161AC_ARG_WITH(
162        [pcsc-provider],
163        [AS_HELP_STRING([--with-pcsc-provider=PATH],[Path to system pcsc provider @<:@system default@:>@])],
164        ,
165        [with_pcsc_provider="detect"]
166)
167dnl ./configure check
168reader_count=""
169for rdriver in "${enable_pcsc}" "${enable_openct}" "${enable_ctapi}"; do
170        test "${rdriver}" = "yes" && reader_count="${reader_count}x"
171done
172if test "${reader_count}" != "x"; then
173        AC_MSG_ERROR([Only one of --enable-pcsc, --enable-openct, --enable-ctapi can be specified!])
174fi
175         
176dnl Checks for programs.
177AC_PROG_CPP
178AC_PROG_INSTALL
179AC_PROG_LN_S
180AC_PROG_MKDIR_P
181AC_PROG_SED
182AC_PROG_MAKE_SET
183
184dnl Add libtool support.
185ifdef(
186        [LT_INIT],
187        [
188                LT_INIT([win32-dll])
189                LT_LANG([Windows Resource])
190        ],
191        [
192                AC_LIBTOOL_WIN32_DLL
193                AC_LIBTOOL_RC
194                AC_PROG_LIBTOOL
195        ]
196)
197
198dnl These required for repository checkout
199AC_ARG_VAR([XSLTPROC], [xsltproc utility])
200AC_ARG_VAR([git], [git])
201AC_CHECK_PROGS([XSLTPROC],[xsltproc])
202AC_CHECK_PROGS([GIT],[git])
203
204AC_MSG_CHECKING([xsl-stylesheets])
205if test "${xslstylesheetsdir}" = "detect"; then
206        xslstylesheetsdir="no"
207        for f in \
208                /usr/share/xml/docbook/stylesheet/nwalsh \
209                /usr/share/xml/docbook/stylesheet/nwalsh/current \
210                /opt/local/share/xsl/docbook-xsl \
211                /sw/share/xml/xsl/docbook-xsl \
212                /usr/share/sgml/docbook/*; do
213
214                test -e "${f}/html/docbook.xsl" && xslstylesheetsdir="${f}"
215        done
216elif test "${xslstylesheetsdir}" != "no"; then
217        test -e "${xslstylesheetsdir}/html/docbook.xsl" || AC_MSG_ERROR([invalid])
218fi
219AC_MSG_RESULT([${xslstylesheetsdir}])
220
221dnl C Compiler features
222AC_C_INLINE
223
224dnl Checks for header files.
225AC_HEADER_STDC
226AC_HEADER_SYS_WAIT
227AC_HEADER_ASSERT
228AC_CHECK_HEADERS([ \
229        errno.h fcntl.h malloc.h stdlib.h \
230        inttypes.h string.h strings.h \
231        sys/time.h unistd.h getopt.h sys/mman.h
232])
233
234dnl Checks for typedefs, structures, and compiler characteristics.
235AC_C_CONST
236AC_TYPE_UID_T
237AC_TYPE_SIZE_T
238AC_HEADER_TIME
239
240dnl Checks for library functions.
241AC_FUNC_ERROR_AT_LINE
242AC_FUNC_STAT
243AC_FUNC_VPRINTF
244AC_CHECK_FUNCS([ \
245        getpass gettimeofday memset mkdir \
246        strdup strerror getopt_long getopt_long_only \
247        strlcpy strlcat
248])
249AC_CHECK_SIZEOF(void *)
250if test "${ac_cv_sizeof_void_p}" = 8; then
251        LIBRARY_BITNESS="64"
252else
253        LIBRARY_BITNESS="32"
254fi
255
256dnl See if socket() is found from libsocket
257AC_CHECK_LIB(
258        [socket],
259        [socket],
260        [
261                LIBS="${LIBS} -lsocket"
262                AC_CHECK_LIB(
263                        [resolv],
264                        [res_query],
265                        [LIBS="${LIBS} -lresolv"]
266                )
267        ]
268)
269
270if test "${WIN32}" = "no"; then
271        dnl dl support
272        AC_CHECK_LIB(
273                [dl],
274                [dlopen],
275                ,
276                [AC_MSG_ERROR([libdl required])]
277        )
278
279        dnl Special check for pthread support.
280        ACX_PTHREAD(
281                [AC_DEFINE(
282                        [HAVE_PTHREAD],
283                        [1],
284                        [Define if you have POSIX threads libraries and header files.]
285                )],
286                [AC_MSG_ERROR([POSIX thread support required])]
287        )
288        CC="${PTHREAD_CC}"
289fi
290
291if test "${enable_minidriver}" = "yes"; then
292        dnl win32 special test for minidriver
293        AC_CHECK_HEADER(
294                [cardmod.h],
295                ,
296                [AC_MSG_ERROR([cardmod.h is not found and required for minidriver])]
297        )
298        AC_DEFINE([ENABLE_MINIDRIVER], [1], [Enable minidriver support])
299fi
300
301AC_ARG_VAR([ZLIB_CFLAGS], [C compiler flags for zlib])
302AC_ARG_VAR([ZLIB_LIBS], [linker flags for zlib])
303if test -z "${ZLIB_LIBS}"; then
304        AC_CHECK_LIB(
305                [z],
306                [inflate],
307                [ZLIB_LIBS="-lz"]
308        )
309fi
310saved_CFLAGS="${CFLAGS}"
311CFLAGS="${CFLAGS} ${ZLIB_CFLAGS}"
312AC_CHECK_HEADERS([zlib.h])
313CFLAGS="${saved_CFLAGS}"
314test -n "${ZLIB_LIBS}" -a "${ac_cv_header_zlib_h}" = "yes" && have_zlib="yes"
315
316case "${enable_zlib}" in
317        no)
318                have_zlib="no"
319        ;;
320        detect)
321                if test "${have_zlib}" = "yes"; then
322                        enable_zlib="yes"
323                else
324                        enable_zlib="no"
325                fi
326        ;;
327esac
328
329if test "${enable_zlib}" = "yes"; then
330        if test "${have_zlib}" = "yes"; then
331                AC_DEFINE([ENABLE_ZLIB], [1], [Use zlib libraries and header files])
332        else
333                AC_MSG_ERROR([zlib linkage required, but no zlib was found])
334        fi
335fi
336
337AC_ARG_VAR([READLINE_CFLAGS], [C compiler flags for readline])
338AC_ARG_VAR([READLINE_LIBS], [linker flags for readline])
339if test -z "${READLINE_LIBS}"; then
340        for l in "" -lncurses -ltermcap; do
341                unset ac_cv_lib_readline_readline
342                AC_CHECK_LIB(
343                        [readline],
344                        [readline],
345                        [READLINE_LIBS="-lreadline ${l}"],
346                        ,
347                        ["${l}"]
348                )
349                test -n "${READLINE_LIBS}" && break;
350        done
351fi
352saved_CFLAGS="${CFLAGS}"
353CFLAGS="${CFLAGS} ${READLINE_CFLAGS}"
354AC_CHECK_HEADERS([readline/readline.h])
355CFLAGS="${saved_CFLAGS}"
356test -n "${READLINE_LIBS}" -a "${ac_cv_header_readline_readline_h}" = "yes" && have_readline="yes"
357
358case "${enable_readline}" in
359        no)
360                have_readline="no"
361        ;;
362        detect)
363                if test "${have_readline}" = "yes"; then
364                        enable_readline="yes"
365                else
366                        enable_readline="no"
367                fi
368        ;;
369esac
370
371if test "${enable_readline}" = "yes"; then
372        if test "${have_readline}" = "yes"; then
373                AC_DEFINE([ENABLE_READLINE], [1], [Use readline libraries and header files])
374        else
375                AC_MSG_ERROR([readline linkage required, but no readline was found])
376        fi
377fi
378
379PKG_CHECK_MODULES(
380        [OPENSSL],
381        [libcrypto >= 0.9.7],
382        [have_openssl="yes"],
383        [PKG_CHECK_MODULES(
384                [OPENSSL],
385                [openssl >= 0.9.7],
386                [have_openssl="yes"],
387                [AC_CHECK_LIB(
388                        [crypto],
389                        [RSA_version],
390                        [
391                                have_openssl="yes"
392                                OPENSSL_LIBS="-lcrypto"
393                        ],
394                        [have_openssl="no"]
395                )]
396        )]
397)
398
399case "${enable_openssl}" in
400        no)
401                have_openssl="no"
402        ;;
403        detect)
404                if test "${have_openssl}" = "yes"; then
405                        enable_openssl="yes"
406                else
407                        enable_openssl="no"
408                fi
409        ;;
410esac
411
412if test "${enable_openssl}" = "yes"; then
413        if test "${have_openssl}" = "yes"; then
414                AC_DEFINE([ENABLE_OPENSSL], [1], [Have OpenSSL libraries and header files])
415        else
416                AC_MSG_ERROR([OpenSSL linkage required, but no OpenSSL was found])
417        fi
418fi
419
420if test "${enable_openct}" = "yes"; then
421        PKG_CHECK_MODULES(
422                [OPENCT],
423                [libopenct],
424                [AC_DEFINE([ENABLE_OPENCT], [1], [Have OpenCT libraries and header files])],
425                [AC_MSG_ERROR([openct requested but not available])]
426        )
427fi
428
429if test "${enable_ctapi}" = "yes"; then
430        AC_DEFINE([ENABLE_CTAPI], [1], [Enable CT-API support])
431fi
432
433if test "${enable_pcsc}" = "yes"; then
434        if test "${WIN32}" != "yes"; then
435                PKG_CHECK_EXISTS(
436                        [libpcsclite],
437                        [PKG_CHECK_MODULES([PCSC], [libpcsclite])]
438                )
439                if test -z "${PCSC_CFLAGS}"; then
440                        case "${host}" in
441                                *-*-darwin*)
442                                        PCSC_CFLAGS="-I/System/Library/Frameworks/PCSC.framework/Headers"
443                                ;;
444                                *)
445                                        PCSC_CFLAGS="-I/usr/include/PCSC"
446                                ;;
447                        esac
448                fi
449        fi
450
451        saved_CFLAGS="${CFLAGS}"
452        CFLAGS="${CFLAGS} ${PCSC_CFLAGS}"
453        # We must cope with mingw32 that does not have winscard.h mingw64 has it.
454        AC_CHECK_HEADERS([winscard.h],,[test "${WIN32}" != "yes" && AC_MSG_ERROR([winscard.h is required for pcsc])])
455        CFLAGS="${saved_CFLAGS}"
456
457        if test "${with_pcsc_provider}" = "detect"; then
458                case "${host}" in
459                        *-*-darwin*)
460                                DEFAULT_PCSC_PROVIDER="/System/Library/Frameworks/PCSC.framework/PCSC"
461                        ;;
462                        *-mingw*|*-winnt*|*-cygwin*)
463                                DEFAULT_PCSC_PROVIDER="winscard.dll"
464                        ;;
465                        *)
466                                DEFAULT_PCSC_PROVIDER="libpcsclite.so.1"
467                        ;;
468                esac
469        else
470                DEFAULT_PCSC_PROVIDER="${with_pcsc_provider}"
471        fi
472        AC_DEFINE_UNQUOTED([DEFAULT_PCSC_PROVIDER], ["${DEFAULT_PCSC_PROVIDER}"], [Default PC/SC provider])
473        AC_DEFINE([ENABLE_PCSC], [1], [Define if PC/SC is to be enabled])
474fi
475
476if test "${enable_man}" = "detect"; then
477        if test "${WIN32}" = "yes"; then
478                enable_man="no"
479        elif test -n "${XSLTPROC}" -a "${xslstylesheetsdir}" != "no"; then
480                enable_man="yes"
481        else
482                enable_man="no"
483        fi
484fi
485
486if test "${enable_man}" = "yes" -o "${enable_doc}" = "yes"; then
487        AC_MSG_CHECKING([XSLTPROC requirement])
488        test -n "${XSLTPROC}" || AC_MSG_ERROR([Missing XSLTPROC])
489        test "${xslstylesheetsdir}" != "no" || AC_MSG_ERROR([Missing xslstylesheetsdir])
490        AC_MSG_RESULT([ok])
491fi
492
493OPENSC_FEATURES=""
494if test "${enable_zlib}" = "yes"; then
495        OPENSC_FEATURES="${OPENSC_FEATURES} zlib"
496        OPTIONAL_ZLIB_CFLAGS="${ZLIB_CFLAGS}"
497        OPTIONAL_ZLIB_LIBS="${ZLIB_LIBS}"
498fi
499if test "${enable_readline}" = "yes"; then
500        OPENSC_FEATURES="${OPENSC_FEATURES} readline"
501        OPTIONAL_READLINE_CFLAGS="${READLINE_CFLAGS}"
502        OPTIONAL_READLINE_LIBS="${READLINE_LIBS}"
503fi
504if test "${enable_openssl}" = "yes"; then
505        OPENSC_FEATURES="${OPENSC_FEATURES} openssl"
506        OPTIONAL_OPENSSL_CFLAGS="${OPENSSL_CFLAGS}"
507        OPTIONAL_OPENSSL_LIBS="${OPENSSL_LIBS}"
508fi
509if test "${enable_openct}" = "yes"; then
510        OPENSC_FEATURES="${OPENSC_FEATURES} openct"
511        OPTIONAL_OPENCT_CFLAGS="${OPENCT_CFLAGS}"
512        OPTIONAL_OPENCT_LIBS="${OPENCT_LIBS}"
513fi
514if test "${enable_pcsc}" = "yes"; then
515        OPENSC_FEATURES="${OPENSC_FEATURES} pcsc(${DEFAULT_PCSC_PROVIDER})"
516        OPTIONAL_PCSC_CFLAGS="${PCSC_CFLAGS}"
517fi
518if test "${enable_ctapi}" = "yes"; then
519        OPENSC_FEATURES="${OPENSC_FEATURES} ctapi"
520fi
521
522AC_DEFINE_UNQUOTED([OPENSC_VERSION_MAJOR], [${OPENSC_VERSION_MAJOR}], [OpenSC version major component])
523AC_DEFINE_UNQUOTED([OPENSC_VERSION_MINOR], [${OPENSC_VERSION_MINOR}], [OpenSC version minor component])
524AC_DEFINE_UNQUOTED([OPENSC_VERSION_FIX], [${OPENSC_VERSION_FIX}], [OpenSC version fix component])
525AC_DEFINE_UNQUOTED([OPENSC_FEATURES], ["${OPENSC_FEATURES}"], [Enabled OpenSC features])
526
527pkcs11dir="\$(libdir)/pkcs11"
528
529AC_SUBST([pkcs11dir])
530AC_SUBST([xslstylesheetsdir])
531AC_SUBST([OPENSC_VERSION_MAJOR])
532AC_SUBST([OPENSC_VERSION_MINOR])
533AC_SUBST([OPENSC_VERSION_FIX])
534AC_SUBST([OPENSC_LT_CURRENT])
535AC_SUBST([OPENSC_LT_REVISION])
536AC_SUBST([OPENSC_LT_AGE])
537AC_SUBST([OPENSC_LT_OLDEST])
538AC_SUBST([WIN_LIBPREFIX])
539AC_SUBST([DEFAULT_PCSC_PROVIDER])
540AC_SUBST([OPTIONAL_ZLIB_CFLAGS])
541AC_SUBST([OPTIONAL_ZLIB_LIBS])
542AC_SUBST([OPTIONAL_READLINE_CFLAGS])
543AC_SUBST([OPTIONAL_READLINE_LIBS])
544AC_SUBST([OPTIONAL_OPENSSL_CFLAGS])
545AC_SUBST([OPTIONAL_OPENSSL_LIBS])
546AC_SUBST([OPTIONAL_OPENCT_CFLAGS])
547AC_SUBST([OPTIONAL_OPENCT_LIBS])
548AC_SUBST([OPTIONAL_PCSC_CFLAGS])
549AC_SUBST([LIBRARY_BITNESS])
550
551AM_CONDITIONAL([ENABLE_MAN], [test "${enable_man}" = "yes"])
552AM_CONDITIONAL([ENABLE_ZLIB], [test "${enable_zlib}" = "yes"])
553AM_CONDITIONAL([ENABLE_READLINE], [test "${enable_readline}" = "yes"])
554AM_CONDITIONAL([ENABLE_OPENSSL], [test "${enable_openssl}" = "yes"])
555AM_CONDITIONAL([ENABLE_OPENCT], [test "${enable_openct}" = "yes"])
556AM_CONDITIONAL([ENABLE_DOC], [test "${enable_doc}" = "yes"])
557AM_CONDITIONAL([WIN32], [test "${WIN32}" = "yes"])
558AM_CONDITIONAL([CYGWIN], [test "${CYGWIN}" = "yes"])
559AM_CONDITIONAL([ENABLE_MINIDRIVER], [test "${enable_minidriver}" = "yes"])
560
561if test "${enable_pedantic}" = "yes"; then
562        enable_strict="yes";
563        CFLAGS="${CFLAGS} -pedantic"
564fi
565if test "${enable_strict}" = "yes"; then
566        CFLAGS="${CFLAGS} -Wall -Wextra"
567fi
568if test "$GCC" = "yes"; then
569        # This should be resolved not ignored.
570        CFLAGS="-fno-strict-aliasing ${CFLAGS}"
571fi
572
573AC_CONFIG_FILES([
574        Makefile
575        doc/Makefile
576        doc/tools/Makefile
577        etc/Makefile
578        src/Makefile
579        src/common/Makefile
580        src/libopensc/Makefile
581        src/libopensc/libopensc.pc
582        src/pkcs11/Makefile
583        src/pkcs15init/Makefile
584        src/scconf/Makefile
585        src/tests/Makefile
586        src/tests/regression/Makefile
587        src/tools/Makefile
588        src/minidriver/Makefile
589        src/minidriver/opensc-minidriver.inf
590        win32/Makefile
591        win32/versioninfo.rc
592        win32/winconfig.h
593        win32/OpenSC.iss
594        win32/OpenSC.wxs
595        MacOSX/Makefile
596        MacOSX/build-package
597        MacOSX/10.5/resources/ReadMe.html
598        MacOSX/10.6/resources/ReadMe.html
599])
600AC_OUTPUT
601
602cat <<EOF
603
604OpenSC has been configured with the following options:
605
606
607Version:                 ${PACKAGE_VERSION}
608User binaries:           $(eval eval eval echo "${bindir}")
609Configuration files:     $(eval eval eval echo "${sysconfdir}")
610XSL stylesheets:         ${xslstylesheetsdir}
611
612man support:             ${enable_man}
613doc support:             ${enable_doc}
614zlib support:            ${enable_zlib}
615readline support:        ${enable_readline}
616OpenSSL support:         ${enable_openssl}
617PC/SC support:           ${enable_pcsc}
618OpenCT support:          ${enable_openct}
619CT-API support:          ${enable_ctapi}
620minidriver support:      ${enable_minidriver}
621
622PC/SC default provider:  ${DEFAULT_PCSC_PROVIDER}
623
624Host:                    ${host}
625Compiler:                ${CC}
626Preprocessor flags:      ${CPPFLAGS}
627Compiler flags:          ${CFLAGS}
628Linker flags:            ${LDFLAGS}
629Libraries:               ${LIBS}
630
631READLINE_CFLAGS:         ${READLINE_CFLAGS}
632READLINE_LIBS:           ${READLINE_LIBS}
633ZLIB_CFLAGS:             ${ZLIB_CFLAGS}
634ZLIB_LIBS:               ${ZLIB_LIBS}
635OPENSSL_CFLAGS:          ${OPENSSL_CFLAGS}
636OPENSSL_LIBS:            ${OPENSSL_LIBS}
637OPENCT_CFLAGS:           ${OPENCT_CFLAGS}
638OPENCT_LIBS:             ${OPENCT_LIBS}
639PCSC_CFLAGS:             ${PCSC_CFLAGS}
640
641EOF
642
Note: See TracBrowser for help on using the repository browser.